AIR Update Manager

« AIR, Flex, and Adobe Media Player | Main | AIR ConnectionManager »

By Rich Tretola | October 1, 2007

3,933 views

[ http://api.tweetmeme.com/button.js?url=http%3A%2F%2Fblog.everythingflex.com%2F2007%2F10%2F01%2Fair-update-manager%2F

UPDATED FOR AIR BETA 3

AIR applications are out in the world with no connection back to home unless you actively code your application to check in from time to time to say hello is there a new version of me available? I have been working on an easy system for keeping AIR applications up to date and I have come up with an UpdateManager that simplifies this process.

Here is how the UpdateManager works.

Upon load of the application the UpdateManager examines the applicationDescriptor property of the NativeApplication.nativeApplication to determine the version of the installed application. This is then stored in the currentVersion property. The constructor accepts one required argument and one optional argument. The first required argument is the URL that holds the version.xml file to test. There is an example of the version.xml file below. The second is a Boolean telling the UpdateManager whether to automatically check for an update or wait until the user triggers the check. It defaults to true. If true, it will load in this XML file, parses it and compares the version property of the XML file with the version that was parsed from the applicationDescriptor. If there is a difference, and the forceUpdate property of the version.xml file is true, the application is automatically updated. If there is a difference and forceUpdate is false, the user is alerted of the available update, given a description of the update, and given the option to update their application The UpdateManager will then perform the update using the File and FileStream classes to download and write the new air file to disk and then the Updater class to complete the update.
The UpdateManager also contains a checkForUpdate() method which will allow your application to provide a way for its user to manually trigger a check for an update. To use the UpdateManager, you will simply need to create an instance of the UpdateManager and pass in the URL of the version.xml file. You may also pass in the optional second argument.

There is also a method in the UpdateManager that will allow you to offer a way for your users to check for available updates anytime the application is running. This method will perform as stated previously if an update is available or will show a message that there are no updates available.

A sample WindowedApplication file:

1
2
3
4
5
6
7
8
9
10
11

<?xml version="1.0" encoding="utf-8"?>
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute">
<mx:Script>
<![CDATA[
import com.everythingflex.air.managers.UpdateManager;
private var um:UpdateManager = new UpdateManager("http://www.yourdomain.com/AIR/UMTest/version.xml",false);
]]>
</mx:Script>
<mx:Button click="um.checkForUpdate()" label="Test for Update"
horizontalCenter="0" verticalCenter="0"/>
</mx:WindowedApplication>

Here is the version.xml file that needs to be on a server accessible by your AIR application. There are several properties that must be set. The currentVersion should be the same as the newest AIR package’s application.xml that you have set in the downloadLocation property. The forceUpdate property will automatically update the user without giving the user the option to say no. The message will be displayed to the user as Details: “message contents” within the Alert window. This is where you can show what new features are in the update.

version.xml file

1
2
3
4
5

<?xml version="1.0" encoding="ISO-8859-1"?>
<currentVersion version=".2"
downloadLocation="http://www.yourdomain.com/AIR/UMTest/UM.air"
forceUpdate="false"
message="Added new features"/>

The UpdateManager class

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131

package com.everythingflex.air.managers
{
import flash.desktop.NativeApplication;
import flash.desktop.Updater;
import flash.events.Event;
import flash.filesystem.File;
import flash.filesystem.FileMode;
import flash.filesystem.FileStream;
import flash.net.URLRequest;
import flash.net.URLStream;
import flash.utils.ByteArray;

import mx.controls.Alert;
import mx.events.CloseEvent;
import mx.rpc.events.FaultEvent;
import mx.rpc.events.ResultEvent;
import mx.rpc.http.HTTPService;

public class UpdateManager
{
// URL of the remote version.xml file
private var versionURL:String;
// load in the applicationDescriptor
private var appXML:XML = NativeApplication.nativeApplication.applicationDescriptor;
private var ns : Namespace = appXML.namespace();
// set the currentVersion information
private var currentVersion:String = appXML.ns::version;
// holder for remote version.xml XML data
private var version:XML;
private var urlStream:URLStream = new URLStream();
private var fileData:ByteArray = new ByteArray();

// the constructor requires the versionURL
public function UpdateManager(versionURL:String,autoCheck:Boolean=true):void{
this.versionURL = versionURL;
if(autoCheck)loadRemoteFile();
}

// load the remote version.xml file
private function loadRemoteFile():void{
var http:HTTPService = new HTTPService();
http.url = this.versionURL;
http.useProxy=false;
http.method = "GET";
http.resultFormat="xml";
http.send();
http.addEventListener(ResultEvent.RESULT,testVersion);
http.addEventListener(FaultEvent.FAULT,versionLoadFailure);
}

/*
test the currentVersion against the remote version file and either alert the user of
an update available or force the update, if no update available, alert user
*/
public function checkForUpdate():Boolean{
if(version == null){
this.loadRemoteFile();
return true;
}
if((currentVersion != version.@version) && version.@forceUpdate == true){
getUpdate();
}else if(currentVersion != version.@version){
Alert.show("There is an update available,\nwould you like to get it now? \n\nDetails:\n" + version.@message, "Choose Yes or No", 3, null, alertClickHandler);
}else{
Alert.show("There are no new updates available", "NOTICE");
}
return true;
}

/*
test the currentVersion against the remote version file and either alert the user of
an update available or force the update
*/
private function testVersion(event:ResultEvent):void{
version = XML(event.result);
if((currentVersion != version.@version) && version.@forceUpdate == true){
getUpdate();
}else if(currentVersion != version.@version){
Alert.show("There is an update available,\nwould you like to " +
"get it now? \n\nDetails:\n" + version.@message,
"Choose Yes or No", 3, null, alertClickHandler);
}
}

/*
Load of the version.xml file failed
*/
private function versionLoadFailure(event:FaultEvent):void{
Alert.show("Failed to load version.xml file from "+
this.versionURL,"ERROR");
}

// handle the Alert window decission
private function alertClickHandler(event:CloseEvent):void {
if (event.detail==Alert.YES){
getUpdate();
}
}

// get the new version from the remote server
private function getUpdate():void{
var urlReq:URLRequest = new URLRequest(version.@downloadLocation);
urlStream.addEventListener(Event.COMPLETE, loaded);
urlStream.load(urlReq);
}

// read in the new AIR package
private function loaded(event:Event):void {
urlStream.readBytes(fileData, 0, urlStream.bytesAvailable);
writeAirFile();
}

// write the newly downloaded AIR package to the application storage directory
private function writeAirFile():void {
var file:File = File.applicationStorageDirectory.resolvePath("Update.air");
var fileStream:FileStream = new FileStream();
fileStream.addEventListener(Event.CLOSE, fileClosed);
fileStream.openAsync(file, FileMode.WRITE);
fileStream.writeBytes(fileData, 0, fileData.length);
fileStream.close();
}

// after the write is complete, call the update method on the Updater class
private function fileClosed(event:Event):void {
var updater:Updater = new Updater();
var airFile:File = File.applicationStorageDirectory.resolvePath("Update.air");
updater.update(airFile,version.@version);
}

}
}

Tweet This! Share this on del.icio.us Digg this! Share this on Reddit Stumble upon something good? Share it on StumbleUpon Share this on Technorati Share this on Facebook

Topics: Adobe AIR | 20 Comments »

20 Responses to “AIR Update Manager”

Doug Schmidt Says:
October 8th, 2007 at 1:04 pm

Rich, have you considered decoupling the version check from the construction of the UpdateManager object? Perhaps extending the EventDispatcher class and sending an Event.COMPLETE event when both the current version and published version resources have been loaded. Otherwise, there is no way for a consumer of the class to know when it is safe to call checkForUpdate(). If you call it too soon (say before the website version.xml has been loaded), the code thumps with null object exceptions.

Search:

Calendar

Tag Cloud

Categories

Archives

Recent Posts

Recent Comments

Share this Site

Social Networks

Upcoming Speaking Events

InsideRIA

My Publications

AIR Update Manager

20 Responses to “AIR Update Manager”

Comments